Песочница Windows 10 — одно из самых интересных и полезных нововведений в последней версии ОС. К сожалению, по умолчанию она доступна только в Профессиональной (Pro) и Корпоративной (Enterprise) версиях системы. Тем не менее, при желании, вы можете установить песочницу Windows 10 (Windows Sandbox) и в домашней редакции системы.
В этой инструкции подробно о том, как включить песочницу в Windows 10 Home с помощью простого скрипта. Непосредственно о том, что такое «Песочница», об использовании этой функции и некоторых дополнительных нюансах в отдельной статье Песочница Windows 10 (Windows Sandbox).
Установка Песочницы в Windows 10 Home
Прежде чем приступить к установке Песочницы в Windows 10 Домашняя, рекомендую учесть следующие моменты:
- Для работы Песочницы требуется включенная виртуализация в БИОС/UEFI. Подробнее: Как включить виртуализацию.
- При тестах данного способа установки песочницы я столкнулся с тем, что её удаление и откат сделанных изменений оказывается затруднительным (точнее — не удалось полностью удалить все следы). Возможно, помогут заранее созданные точки восстановления, но гарантий дать не могу. Либо используйте функцию удаления Песочницы, которая реализована в самом скрипте.
- Гарантировать исправную работу Песочницы после установки данным способом нельзя. Например, можно столкнуться с ошибкой Не удалось инициализировать Песочницу Windows и другими.
Для установки песочницы в Windows 10 Домашняя можно использовать простой bat-файл, который, с помощью DISM установит все необходимые компоненты в домашней версии системы. Такой файл можно сделать самостоятельно, используя код, приведенный ниже (см. Как создать bat файл).
@echo off
echo Checking for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
echo Permission check result: %errorlevel%
REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
echo Requesting administrative privileges...
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
echo Running created temporary "%temp%\getadmin.vbs"
timeout /T 2
"%temp%\getadmin.vbs"
exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
pushd "%CD%"
CD /D "%~dp0"
echo Batch was successfully started with admin privileges
echo .
cls
GOTO:menu
:menu
Title Sandbox Installer
echo Select Action
echo 1 Install
echo 2 Uninstall
echo 3 Exit
set /p uni= Enter your option:
if %uni% ==1 goto :in
if %uni% ==2 goto :un
if %uni% ==3 goto :ex
:in
cls
Title Install Sandbox
pushd "%~dp0"
dir /b %SystemRoot%\servicing\Packages\*Containers*.mum >sandbox.txt
for /f %%i in ('findstr /i . sandbox.txt 2^>nul') do dism /online /norestart /add-package:"%SystemRoot%\servicing\Packages\%%i"
del sandbox.txt
Dism /online /enable-feature /featurename:Containers-DisposableClientVM /LimitAccess /ALL /NoRestart
goto :remenu
:un
cls
Title Uninstall Sandbox
pushd "%~dp0"
Dism /online /disable-feature /featurename:Containers-DisposableClientVM /NoRestart
dir /b %SystemRoot%\servicing\Packages\*Containers*.mum >sandbox.txt
for /f %%i in ('findstr /i . sandbox.txt 2^>nul') do dism /online /norestart /remove-package:"%SystemRoot%\servicing\Packages\%%i"
del sandbox.txt
goto :remenu
:remenu
cls
echo Restart computer?
echo 1 Yes
echo 2 No
set /p uni= Input 1 or 2:
if %uni% ==1 goto :re
if %uni% ==2 goto :ex
:re
shutdown /r /t 0 /f
goto :ex
:ex
exit
А при желании его можно скачать с сайта автора скрипта (сайт на немецком, ссылка на загрузку — Sandbox Installer.zip на указанной странице). После запуска файла от имени администратора потребуется выбрать опцию установки (Install), введя 1 и дождаться завершения процесса.
После завершения установки компонентов вам будет предложено перезагрузить компьютер, сделайте это (в текущей версии скрипта требуется ввести 1 для подтверждения перезагрузки). При перезагрузке будет проведена настройка системы и новых компонентов, а после неё вы увидите новый пункт в меню «Пуск» — Windows Sandbox, запускающий песочницу.
О возможных ошибках (например, 0x80070002 «Не удается найти указанный файл») при запуске, их исправлении и возможностях настройки песочницы в упоминавшейся выше инструкции про использование песочницы Windows 10.
Список устройств воспроизведения и записи — один из элементов настроек Windows 10, наиболее часто упоминаемый в материалах на тему решения проблем со звуком, его выводом и записью, работой микрофона.
Иногда, запустив приложение «Камера» в Windows 10 вы можете получить сообщение об ошибке: «Не удается найти камеру. Убедитесь, что камера правильно подключена и установлена, что ее не блокирует антивирусное программное обеспечение и что драйверы камеры не требуют обновления» с кодом 0xA00F4244 NoCamerasAreAttached.
Если ваш ноутбук оснащен современным тачпадом, для которого установлены оригинальные драйверы и Windows 10, с большой вероятностью он поддерживает различные жесты, которые можно выполнять несколькими пальцами. При необходимости вы можете изменить жесты с тремя или четырьмя пальцами, в том числе и для того, чтобы запускать ваши программы или встроенные системные утилиты ОС.
Одна из новых особенностей Windows 10 — размытый фон при вводе пароля на экране блокировки (входа в систему). И, как оказалось, многим пользователям этот эффект пришелся не по душе, более того, размытие тормозит на некоторых компьютерах.
Как правило, удаление обновлений Windows 10 сравнительно несложная задача, выполнить которую можно через соответствующий элемент панели управления, либо используя утилиту командной строки wusa.exe, о чем я подробно писал в материале 
В Windows 10 последней версии, зайдя в утилиту «Управление дисками», а также в DiskPart или сторонних утилитах управления разделами дисков вы можете обнаружить скрытый диск с меткой PortableBaseLayer, объемом 8 Гб с файловой системой NTFS, в статусе которого заявлено «Только чтение».
